[GAP Forum] request

[Iverson, Joseph W [MATH]]

Dear Zohreh,

Any nontrivial semidirect product 2^3:7 is isomorphic to the affine linear group AGL(1,8). There is a nice post on math overflow that explains why the Schur multiplier is trivial: https://mathoverflow.net/questions/191885/what-is-the-schur-multiplier-of-the-affine-linear-group-agln-q

To compute it in GAP, you can use AbelianInvariantsMultiplier. Note that this can be slow for large groups:
 
gap> #Create the semidirect product
gap> V:=GF(2)^3;
( GF(2)^3 )
gap> H:=SylowSubgroup(GL(3,2),7);
Group([ <an immutable 3x3 matrix over GF2> ])
gap> G:=SemidirectProduct(H,V);
<matrix group of size 56 with 2 generators>
gap> 
gap> #Verify it has the correct form
gap> StructureDescription(G);
"(C2 x C2 x C2) : C7"
gap> 
gap> #Compute the Schur multiplier
gap> AbelianInvariantsMultiplier(G);
[  ]

For larger groups, the cohomolo package by Derek Holt works much faster, computing the p-parts of the Schur multiplier one piece at a time. To use it, we first have to find an isomorphic permutation group:

gap> LoadPackage("cohomolo");
──────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────
Loading  cohomolo 1.6.6 (Computing Cohomology groups and Schur Multipliers)
by Derek Holt (http://homepages.warwick.ac.uk/staff/D.F.Holt/).
Homepage: https://gap-packages.github.io/cohomolo
──────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────
true
gap> 
gap> #Find an isomorphic permutation group
gap> g:=Image( IsomorphismPermGroup(G) );
Group([ (3,5,11,7,15,13,9)(4,6,12,8,16,14,10), (2,10)(4,12)(6,14)(8,16) ])
gap> 
gap> #Find all prime divisors of the order of g
gap> primes:=PrimeDivisors(Size(g));
[ 2, 7 ]
gap> 
gap> #For each prime dividing the order of g, compute the p-part of the Schur multiplier
gap> mult:=[];;
gap> for p in primes do
>       #create a CHR object as required by the "cohomolo" package
>       chr:=CHR(g,p);;
>       #compute the p-part of the Schur multiplier and add it to our list
>       mult:=Concatenation(mult,SchurMultiplier(chr));;
> od;
The Sylow p-subgroup of the group is cyclic - so the multiplier is trivial.
gap> 
gap> #Display the result
gap> mult;
[  ]

I hope this helps!

Best regards,
Joey Iverson

Assistant Professor
Department of Mathematics
Iowa State University

On 6/18/19, 1:18 PM, "zohreh sayanjali" <zohrehsayanjali at gmail.com> wrote:

    Dear  GAP Forum,
     I need to calculate the Schur multiplier of the group " 2^3:7" by GAP.
    
    I would really appreciate it if you help me to find it.
    Regards,
    Zohreh sayanjali
    _______________________________________________
    Forum mailing list
    Forum at gap-system.org
    https://mail.gap-system.org/mailman/listinfo/forum